Je eigen portfolio op al je devices

Eerder schreef ik al hoe je een overzicht kan maken in Excel maar daar zitten (in mijn geval) wel wat haken en ogen aan: ik gebruik privé een Mac en daar werkt de import van de huidige koersen niet op. Daarnaast zou ik graag op al mijn devices het overzicht kunnen raadplegen. Dus heb ik me verdiept in andere mogelijkheden en kwam al snel uit bij Google Sheets. De voordelen van Google sheets zijn:

• het is gratis
• is te gebruiken op (bijna) alle devices met een internetverbinding
• er zijn verschillende plugins waarmee je extra functies kan toevoegen aan je portfolio

Om Google sheets te kunnen gebruiken heb je een Google account nodig, ik ga er vanuit dat je die hebt en anders moet je dat eerst regelen (google maar even ;-))

Je eigen portfolio op al je devices met google sheets

Gaan naar Google sheets, maak een nieuw bestand aan en geef het een naam:

Je kan aan je sheet een invulformulier koppelen zodat je makkelijk je portfolio kan bijwerken. Voor het bijhouden van je portfolio heb je de volgende gegevens nodig:

• exchange: waar je je muntje koopt en verkoopt
• coin: met welk muntje heb je gehandeld
• trade: buy of sell
• price: wat was de prijs (in BTC)
• amount: hoeveel coins heb je gehandeld

Het valt je misschien op dat ik de fee die je moet betalen niet registreer, mocht je dit wel willen bijhouden dan moet je dit zelf nog toevoegen aan je invulformulier. Wanneer het invulformulier klaar is wordt je sheet automatisch aangepast.

Het invulformulier

Klik in het menu op Tools –> Create form. Er wordt een nieuw tabblad geopend waarin je je formulier kunt maken. Maak de vijf vragen en klik op het oogje rechts bovenin om het formulier te testen. Ga daarna weer naar het tabblad Cryptocurrency portfolio – Google Sheets en je ziet (links onderin) dat er een nieuw tabblad (Form Responses 1) is toegevoegd aan je Sheet. Klik op dat tabblad!

Klik in het menu op Form –> Go to live form en vul een aantal aankopen in. Je kan overigens ook direct in dit tabblad je gegevens invoeren. In dat geval hoef je kolom A (Timestamp) niet in te vullen. Let op bij het invoeren: Google sheets gebruikt de punt (.) als decimaal!

In het tabblad Form Responses voeg ik zelf nog een kolom (G) toe “Total BTC” en vul de cel

G2: =F2*E2

Omdat we deze gegevens uiteindelijk in een mooi overzicht willen zetten moeten er nog een aantal Named ranges worden toegevoegd. Bij een aantal formules verwijzen we hier naar.

Klik in het menu op Data –> Named Ranges. Er verschijnt nu rechts in het scherm een nieuwe balk. Klik op “Add a range” en voer naam en range in:

• naam: frExchange en range selecteer cel B2 t/m B500
• naam: frCoin en range: selecteer cel C2 t/m C500
• naam: frTrade en range: selecteer cel D2 t/m D500
• naam: frPrice en range: selecteer cel E2 t/m E500
• naam: frAmount en range: selecteer cel F2 t/m F500
• naam: frTotal en range: selecteer cel G2 t/m G500

Het kan zijn dat je een error melding krijgt maar die kun je negeren.

Settings

Nu is het tijd om een tabblad toe te voegen waarin een aantal “hulpjes” komen die we nodig hebben voor het vervolg. Immers naarmate er meer trades worden ingevoerd komen een aantal waardes vaker voor in de kolom Exchange en Coins. Wat we nu gaan doen is een lijst maken met unieke gegevens voor deze twee kolommen.

Voeg een nieuw tabblad toen (klik op + links onderin) en geef het de naam “Settings” (klik op tabblad met rechtermuisknop en selecteer Rename). Vervolgens zet je in cel A1 Exchanges en B1 Coins en vul de cellen

A2: =SORT(UNIQUE(frExchange))
B2: =SORT(UNIQUE(frCoin))

En voeg twee Named Range’s toe:

• naam: lsExchange en range selecteer cel A2 t/m A30
• naam: lsCoin en range: selecteer cel B2 t/m B30

Exchange

Voeg een nieuw tabblad toe en hernoem het naar Exchange. Hier gaan we een overzicht maken per exchange. Het idee is om het dynamisch te maken, hiervoor maken we een dropdown keuzemenu:  selecteer cel A1 en open in het menu Data –> Data validation… en vul als volgt in.

Cel A1 is nu veranderd in een dropdown keuzemenu

Hieronder komt het overzicht, eerst de kopjes:

En dan de formules:

A4: =IFERROR(SORT(UNIQUE({FILTER(frCoin, frExchange=$A$1)})),"")
B4: =IF(ISBLANK(A4),"", SUMIFS(frAmount,frCoin,A4,frTrade,"Buy"))
C4: =IF(ISBLANK(A4),"", SUMIFS(frTotal,frCoin,A4,frTrade,"Buy"))
D4: =iferror(AVERAGE.WEIGHTED(filter(frPrice,frTrade="Buy",frCoin=A4),filter(frAmount,frTrade ="Buy",frCoin=A4)),"")

E4: =IF(ISBLANK(A4),"", SUMIFS(frAmount,frCoin,A4,frTrade,"Sell"))
F4: =IF(ISBLANK(A4),"", SUMIFS(frTotal,frCoin,A4,frTrade,"Sell"))
G4: =iferror(AVERAGE.WEIGHTED(filter(frPrice,frTrade="Sell",frCoin=A4),filter(frAmount,frTrade ="Sell",frCoin=A4)),"")

H4: =IF(F4=0,"", IFERROR((G4-D4)/D4,""))
I4: =if(A4="","",B4-E4)

Kopieer de formules in B4 t/m I4 naar beneden tot en met bijvoorbeeld rij 30. Dit kun je doen door de cellen B4 t/m I4 te selecteren, er verschijnt een lichtblauwe lijn om de selectie en rechts een licht blauw blokje, klik daar op en trek het naar beneden.

Wanneer je in cel A1 een andere exchange selecteert wordt het overzicht aangepast met de trades die je op die exchange hebt gemaakt.

Hits: 797